Utilisateur:VIGNERON/Domaine public
Cette page sert à lister les personnes entrant dans le domaine public l'année à venir (voir aussi Aide:Droit d’auteur).
Elle s'appuie notamment sur des requêtes SPARQL sur les données de Wikidata et la bibliothèque nationale de France (BnF).
- À faire
importer le modèle Listeriaactiver Listeria sur la Wikisource francophone- ajouter des requêtes plus précises (par nationalité, par occupation précise, avec des œuvres ayant déjà un élément Wikidata, etc.)
- ajouter des requêtes vers d'autres bases de données
- utilisation de Duplicity depuis Petscan Requête portant sur les auteurs sans élément (voir le lien "Check Wikidata")
- regarder la question des ouvrages collectifs
Liste de personnes
[modifier]Depuis Wikidata
[modifier]Personnes
[modifier]Personnes mortes en 1954 et étant écrivaines
[modifier]Première requête générale sur toutes les personnes mortes en 1954 et étant écrivaines (quelque soit la nationalité ou les autres données). Le calcul est basique et cherche les personnes morts il y a 70 ans donc entrant en théorie dans le domaine au 1er janvier 2025, il peut exister des exceptions selon la loi locale.
SELECT * WHERE {
?item wdt:P570 ?date ; #personne ayant une date de mort
wdt:P106 wd:Q36180 . #personne étant écrivaine
FILTER (year(?date) = (year(NOW())-70) ) #la date de mort est située il y a 70 ans
}
Seulement les femmes
[modifier]Première requête générale sur toutes les personnes mortes en 1954 et étant écrivaines (quelque soit la nationalité ou les autres données). Le calcul est basique et cherche les personnes morts il y a 70 ans donc entrant en théorie dans le domaine au 1er janvier 2025, il peut exister des exceptions selon la loi locale.
SELECT * WHERE {
?q wdt:P570 ?date ; #personne ayant une date de mort
wdt:P106 wd:Q36180 ; #personne étant écrivaine
wdt:P21 wd:Q6581072 . #personne de genre féminin
FILTER (year(?date) = (year(NOW())-70) ) #la date de mort est située il y a 70 ans
}
- Petscan : Autrices déjà sur Wikisource décédées en 1952 https://petscan.wmflabs.org/?psid=23494112
Personnes ayant déjà une page sur la Wikisource francophone
[modifier]Personnes mortes 1954 ayant déjà une page Auteur: sur la Wikisource francophone
SELECT * WHERE {
?q wdt:P570 ?date ; #personne ayant une date de mort
wdt:P106 wd:Q36180 . #personne étant écrivaine
FILTER (year(?date) = (year(NOW())-70) ) #la date de mort est située il y a 70 ans
?page schema:about ?q ; schema:isPartOf <https://fr.wikisource.org/> . #personne ayant une page sur la Wikisource francophone
}
On peut aussi exploiter la catégorie Catégorie:Décès en 1954, notamment la recouper avec Wikidata à l’aide de PetScan : petscan.wmflabs.org/ (ex. Auteurs morts en 1952 et lien vers Wikidata si il existe : https://petscan.wmflabs.org/?psid=23464338)
Personnes mortes entre 1900 et 2000
[modifier]Afin de préparer les futures entrées dans le domaine public, voici les personnes mortes entre 1900 et 2000 dont la date de mort est d'une précision inférieure à l'année.
SELECT DISTINCT ?q ?precision ?date WHERE {
?q p:P570 ?node ; #personne ayant une date de mort
wdt:P106 wd:Q36180 . #personne étant écrivaine
?node wikibase:rank ?rank ;
psv:P570 [ wikibase:timePrecision ?precision ; wikibase:timeValue ?date ] . #précision et valeur de la date de mort
FILTER ( ?rank != wikibase:DeprecatedRank ) #on retire les dates de mort dépréciées
FILTER ( ?precision < 9 ) #la date de mort est d'une précision inférieure à l'année
FILTER ( year(?date) > 1900 && year(?date) < 2000 ) #la date de mort est entre 1900 et 2000
}
Éditions
[modifier]À partir des personnes, on peut liter les éditions possiblement dans le domaine public (dont l'auteur est mort depuis plus de 70 ans).
SELECT * WHERE {
?item wdt:P570 ?date ; #personne ayant une date de mort
wdt:P106 wd:Q36180 . #personne étant écrivaine
FILTER (year(?date) = (year(NOW())-70) ) #la date de mort est située il y a 70 ans
?edition wdt:P50 ?item . #édition de cette personne
OPTIONAL { ?edition wdt:P4258 ?idGallica } #identifiant Gallica de cette édition
OPTIONAL { ?edition wdt:P724 ?id } #identifant Internet Archive
}
SELECT * WHERE {
?item wdt:P570 ?date ; #personne ayant une date de mort
wdt:P106 wd:Q36180 . #personne étant écrivaine
FILTER (year(?date) = (year(NOW())-70) ) #la date de mort est située il y a 70 ans
?edition wdt:P50 ?item ; #édition de cette personne
wdt:P407 wd:Q150 . #cette édition est en français
OPTIONAL { ?edition wdt:P4258 ?idGallica } #identifiant Gallica de cette édition
OPTIONAL { ?edition wdt:P724 ?id } #identifant Internet Archive
}
Depuis la BnF
[modifier]Liste pré-construite "Auteurs morts en 1954" : https://data.bnf.fr/date/1954/person_death/page1
- liste des auteurs morts en 1953, avec leur date de décès, et leur langue d'expression
Autres sources ?
[modifier]Autres sources à explorer (IdRef ? Persee https://data.persee.fr/sparql ?)
Persee :
- lien en dur : https://data.persee.fr/sparql?default-graph-uri=&query=select+distinct+%3Fp+where+{%0D%0A%3Fp+a+foaf%3APerson+%3B%0D%0A+schema%3AdeathDate+"1952"^^<http%3A%2F%2Fwww.w3.org%2F2001%2FXMLSchema%23gYear>+.%0D%0A}&format=text%2Fhtml&timeout=0&debug=on&run=+Run+Query+
- Requête :
select distinct ?p where { ?p a foaf:Person ; schema:deathDate "1952"^^<http://www.w3.org/2001/XMLSchema#gYear> . }
SELECT DISTINCT ?q ?endpoint WHERE {
?q wdt:P5305 ?endpoint ; #chose possédant un point d'accès SPARQL
(wdt:P2093|wdt:P127|wdt:P137) ?bibliothèque . #en liant avec une bibliothèque -- à affiner pour tout catalogue bibliographique ?
?bibliothèque wdt:P31/wdt:P279* wd:Q7075 .
}